Currently,
R and
S must both be polynomial rings over the same base field.
This function first checks to see whether M will be a finitely generated R-module via F. If not, an error message describing the codimension of M/(vars of S)M is given (this is equal to the dimension of R if and only if M is a finitely generated R-module.
Assuming that it is, the push forward
F_*(M) is computed. This is done by first finding a presentation for
M in terms of a set of elements that generates
M as an
S-module, and then applying the routine
coimage to a map whose target is
M and whose source is a free module over
R.
Example: The Auslander-Buchsbaum formula
Let's illustrate the Auslander-Buchsbaum formula. First construct some rings and make a module of projective dimension 2.
i1 : R4 = ZZ/32003[a..d];
|
i2 : R5 = ZZ/32003[a..e];
|
i3 : R6 = ZZ/32003[a..f];
|
i4 : M = coker genericMatrix(R6,a,2,3)
o4 = cokernel | a c e |
| b d f |
2
o4 : R6-module, quotient of R6
|
i5 : pdim M
o5 = 2
|
Create ring maps.
i6 : G = map(R6,R5,{a+b+c+d+e+f,b,c,d,e})
o6 = map(R6,R5,{a + b + c + d + e + f, b, c, d, e})
o6 : RingMap R6 <--- R5
|
i7 : F = map(R5,R4,random(R5^1, R5^{4:-1}))
o7 = map(R5,R4,{8699a - 15822b + 2367c - 839d - 1988e, 10220a + 799b - 8666c + 245d - 9844e, 11378a + 12401b + 478c + 1520d + 12409e, 11281a + 2111b - 6891c + 4686d - 9077e})
o7 : RingMap R5 <--- R4
|
The module M, when thought of as an R5 or R4 module, has the same depth, but since depth M + pdim M = dim ring, the projective dimension will drop to 1, respectively 0, for these two rings.
i8 : P = pushForward(G,M)
o8 = cokernel | c -de |
| d bc-ad+bd+cd+d2+de |
2
o8 : R5-module, quotient of R5
|
i9 : pdim P
o9 = 1
|
i10 : Q = pushForward(F,P)
3
o10 = R4
o10 : R4-module, free, degrees {0, 1, 0}
|
i11 : pdim Q
o11 = 0
|
Example: generic projection of a homogeneous coordinate ring
We compute the pushforward N of the homogeneous coordinate ring M of the twisted cubic curve in P^3.
i12 : P3 = QQ[a..d];
|
i13 : M = comodule monomialCurveIdeal(P3,{1,2,3})
o13 = cokernel | c2-bd bc-ad b2-ac |
1
o13 : P3-module, quotient of P3
|
The result is a module with the same codimension, degree and genus as the twisted cubic, but the support is a cubic in the plane, necessarily having one node.
i14 : P2 = QQ[a,b,c];
|
i15 : F = map(P3,P2,random(P3^1, P3^{-1,-1,-1}))
5 3 9 5 1 1 4
o15 = map(P3,P2,{9a + 2b + 4c + d, 2a + -b + -c + --d, -a + -b + -c + -d})
3 2 10 2 3 2 5
o15 : RingMap P3 <--- P2
|
i16 : N = pushForward(F,M)
o16 = cokernel {0} | 18794985ab-26003670b2-7420800ac-30407610bc+13553760c2 6264995a2-22459580b2-34923300ac+30115520bc+34811260c2 2240937658055745000b3-5019829043310873000b2c-178819662917614320ac2+3831308830354717440bc2-355965770985945120c3 0 |
{1} | -1078924a+32233454b-5784982c 18450410a+2653508b-31168804c -76996258478797042a2-1756303018671898532ab+2614477989241486412b2+1409341793551870387ac-1518476867383501454bc-1226808509776415806c2 49042a3+1050808a2b-3294916ab2+4751864b3-1003799a2c-60584abc-2690556b2c+2299196ac2+260208bc2-1603948c3 |
2
o16 : P2-module, quotient of P2
|
i17 : hilbertPolynomial M
o17 = - 2*P + 3*P
0 1
o17 : ProjectiveHilbertPolynomial
|
i18 : hilbertPolynomial N
o18 = - 2*P + 3*P
0 1
o18 : ProjectiveHilbertPolynomial
|
i19 : ann N
3 2 2 3 2
o19 = ideal(49042a + 1050808a b - 3294916a*b + 4751864b - 1003799a c -
-----------------------------------------------------------------------
2 2 2 3
60584a*b*c - 2690556b c + 2299196a*c + 260208b*c - 1603948c )
o19 : Ideal of P2
|
Note: these examples are from the original Macaulay script by David Eisenbud.