divisor -- Constructor for (Weil/Q/R)-divisors

Synopsis

Usage:
D1 = divisor(l1, l2, Unsafe=>u, CoeffType=>v, AmbRing=>R)
D2 = divisor( I )
D3 = divisor( f )
D4 = divisor( l3, Unsafe=>u, CoeffType=>v, AmbRing=>R)
Inputs:
- l1, a basic list, which describes the list of coefficients in integers
- l2, a basic list, which describes the list of height one prime ideals that corresponds to codimension one irreducible subspaces
- I, an ideal
- f, a ring element
- l3, a basic list, a list of pairs c, P where c is a coefficient of type v and P is a prime ideal
- u, a Boolean value, if true, no checking of the primes (to see if they are height one etc.) will be attempted, false by default
- v, a Boolean value, default is ZZ. If ZZ, QQ, RR, then the divisor will be a WDiv, QDiv, or RDiv. Other coefficients can be specified too which yields a BasicDiv
- R, a ring, an option to specify a particular ambient ring
Optional inputs:
- AmbRing => ..., -- Constructor for (Weil/Q/R)-divisors
- CoeffType => ..., -- Constructor for (Weil/Q/R)-divisors
- Unsafe => ..., -- Constructor for (Weil/Q/R)-divisors
Outputs:
- D1, an object of class WDiv
- D2, an object of class WDiv
- D3, an object of class WDiv
- D4, an object of class WDiv

The general function for constructing Weil divisors. If f is an element of a fraction field, it is handled appropriately.

i1 : R = QQ[x,y,z]

o1 = R

o1 : PolynomialRing

i2 : D = divisor({1,2,3}, {ideal(x), ideal(y), ideal(z)})

o2 = 3*Div(z) + 2*Div(y) + 1*Div(x) of R

o2 : WDiv

i3 : E = divisor(x*y^2*z^3)

o3 = 3*Div(z) + 2*Div(y) + 1*Div(x) of R

o3 : WDiv

i4 : F = divisor(ideal(x*y^2*z^3))

o4 = 3*Div(z) + 2*Div(y) + 1*Div(x) of R

o4 : WDiv

i5 : G = divisor({{1, ideal(x)}, {2, ideal(y)}, {3, ideal(z)}})

o5 = 3*Div(z) + 2*Div(y) + 1*Div(x) of R

o5 : WDiv

Creates the same Weil divisor with coefficients 1, 2 and 3 in four different ways

i6 : R = QQ[x,y,z]/ideal(x^2-y*z)

o6 = R

o6 : QuotientRing

i7 : D = divisor({2}, {ideal(x,y)})

o7 = 2*Div(x, y) of R

o7 : WDiv

i8 : E = divisor(y)

o8 = 2*Div(y, x) of R

o8 : WDiv

Creates the same Weil divisor in two different ways

i9 : R = ZZ/7[x,y]

o9 = R

o9 : PolynomialRing

i10 : D = divisor({-1/2, 2/1}, {ideal(y^2-x^3), ideal(x)}, CoeffType=>QQ)

o10 = -1/2*Div(-x^3+y^2) + 2*Div(x) of R

o10 : QDiv

Constructs a Q-divisor

i11 : R = ZZ/11[x,y,u,v]/ideal(x*y-u*v)

o11 = R

o11 : QuotientRing

i12 : D = divisor({1.1, -3.14159}, {ideal(x,u), ideal(x, v)}, CoeffType=>RR)

o12 = 1.1*Div(x, u) + -3.14159*Div(x, v) of R

o12 : RDiv