First LieAlgebra Tutorial -- A tutorial of the package GradedLieAlgebras

In this elementary tutorial, we give a brief introduction on how to use the package GradedLieAlgebras.

The most common way to construct a Lie algebra is by means of the constructor lieAlgebra.

i1 : L1 = lieAlgebra({a,b}, {})

o1 = L1

o1 : LieAlgebra

i2 : computeLie 5

o2 = {2, 1, 2, 3, 6}

o2 : List

The above list is the dimensions of the free Lie algebra on two generators in degrees 1 to 5. To get an explicit basis in a certain degree, use basisLie.

i3 : basisLie 2

o3 = {[b, a]}

o3 : List

i4 : basisLie 3

o4 = {[a, b, a], [b, b, a]}

o4 : List

The basis elements in degree 3 above should be interpreted as [a,[b,a]] and [b,[b,a]]. To multiply two elements, use multLie.

i5 : prod=multLie([a,b],[a,a,b])

o5 = {{-1, 1}, {[a, b, a, b, a], [b, a, a, b, a]}}

o5 : List

The output above should be interpreted as -[a,[b,[a,[b,a]]]] + [b,[a,[a,[b,a]]]], that is, we use the right associative convention for Lie monomials, see monomialLie. The output from multLie is a linear combination of the basis elements of degree 5.

i6 : basisLie 5

o6 = {[a, a, a, b, a], [b, a, a, b, a], [a, b, a, b, a], [b, b, a, b, a], [a,
     ------------------------------------------------------------------------
     b, b, b, a], [b, b, b, b, a]}

o6 : List

An expression like prod above may be used as a relation in a Lie algebra.

i7 : L2=lieAlgebra({a,b},{prod})

o7 = L2

o7 : LieAlgebra

i8 : computeLie 5

o8 = {2, 1, 2, 3, 5}

o8 : List

As expected, the dimension in degree 5 of L2 is one less than that of L1. Each relation in the second argument to the constructor lieAlgebra is a general Lie expression, generalExpressionLie, see How to write Lie elements.

First LieAlgebra Tutorial -- A tutorial of the package GradedLieAlgebras

See also